入出庫処理をまとめて、データベースの項目を追加する　【VBA在庫管理#23】

体重が3kg増えました(照)、どうもoReです。

今回は、データベースの項目を増やしていきます。

だって、在庫数だけ数えてもねぇ…
いろんなデータがあると解析できると思うの。

入庫処理・出庫処理プログラムまとめ

Mainフォームに入庫処理と出庫処理を書いていますが、
項目を追加する場合、この2つのプロシージャに追加しないと
いけなくなるので、今のうちにまとめちゃいましょう。

入庫処理と出庫処理のコードを見るとほぼ同じですよね。

違いといえば

・在庫数の増減の部分

在庫数をプラスするか、マイナスするかの違い。

'入庫処理
Knskcell.Offset(0, 4) = Knskcell.Offset(0, 4) + TextBox3
'出庫処理
Knskcell.Offset(0, 4) = Knskcell.Offset(0, 4) - TextBox3

・入出庫履歴シートへの入庫か出庫かの出力部分

入庫と出力するか、出庫と出力するかの違い。

'入庫処理
.Range("I3") = "入庫"
'出庫処理
.Range("I3") = "出庫"

・メッセージの部分

『入庫しました。』と表示するか、『出庫しました。』と表示するかの違い。

'入庫処理
MsgBox "入庫しました。"
'出庫処理
MsgBox "出庫しました。"

のみです。

Mainフォームに新たにNyuSyukkoプロシージャを作成します。
共通する部分はコピペしてサクッとまとめましょう。

　　↓こんな感じ

'入出庫処理
Private Sub NyuSyukko(ByVal NS As String)　'引数NSは文字列で、入庫か出庫をちょうだい!!
　　Dim Knskcell As Range

　　If ComboBox1 = "" Then
　　　　MsgBox "入出庫者名を入力してください。"
　　ElseIf TextBox2 = "" Then
　　　　MsgBox "バーコードデータを入力してください。"
　　ElseIf TextBox3 = "" Then
　　　　MsgBox "個数を入力してください。"
　　Else
　　　　Set Knskcell = Range("C:C").Find(what:=TextBox2, lookat:=xlWhole)
　　　　If Knskcell Is Nothing Then
　　　　　　MsgBox "部品が登録されていません。"
　　　　Else
　　　　　　If NS = "入庫" Then　'引数NSが入庫の場合
　　　　　　　　Knskcell.Offset(0, 4) = Knskcell.Offset(0, 4) + TextBox3
　　　　　　ElseIf NS = "出庫" Then　'引数NSが出庫の場合
　　　　　　　　Knskcell.Offset(0, 4) = Knskcell.Offset(0, 4) - TextBox3
　　　　　　End If
　　　　　　'ここに項目追加処理を書くよ
　　　　　　With Sheet2　'入出庫履歴シートへ出力
　　　　　　　　.Rows(Rows.Count).Delete
　　　　　　　　.Rows(3).Insert
　　　　　　　　.Range("B3") = Now
　　　　　　　　.Range("C3") = ComboBox1
　　　　　　　　.Range("D3") = Knskcell.Offset(0, -1)
　　　　　　　　.Range("E3") = Knskcell.Offset(0, 1)
　　　　　　　　.Range("F3") = Knskcell.Offset(0, 2)
　　　　　　　　.Range("G3") = Knskcell.Offset(0, 3)
　　　　　　　　.Range("H3") = TextBox3 * 1
　　　　　　　　.Range("I3") = NS　'引数NSの文字列を出力
　　　　　　End With
　　　　　　Call UserForm_Initialize
　　　　　　MsgBox NS & "しました。"　'引数NSの文字列に　しました。を合体
　　　　End If
　　End If
End Sub

コマンドボタン1クリックを変更

'出庫ボタンクリック
Private Sub CommandButton1_Click()
　　Call NyuSyukko("出庫")　'引数に文字列の出庫を渡すよ!!
End Sub

コマンドボタン2クリックを変更

'入庫ボタンクリック
Private Sub CommandButton2_Click()
　　Call NyuSyukko("入庫")　'引数に文字列の入庫を渡すよ!!
End Sub

動作確認しましょう。
ちゃんと、入出庫していますか?

データベースの項目追加

とりあえず、以下の項目を追加します。

・最大在庫数・最少在庫数・過剰在庫数・在庫不足数
・部品注文数・部品単価・部品合計金額

　　↓データベースシートに追加

では、追加した項目の処理を書いていきましょう。

過剰在庫数処理

・過剰在庫数=在庫数-最大在庫数

With Knskcell
　　.Offset(0, 7) = .Offset(0, 4) - .Offset(0, 5)　'過剰在庫数=在庫数-最大在庫数
End With

在庫不足数処理

・在庫不足数=最少在庫数-在庫数

With Knskcell
　　.Offset(0, 7) = .Offset(0, 4) - .Offset(0, 5)　'過剰在庫数=在庫数-最大在庫数
　　.Offset(0, 8) = .Offset(0, 6) - .Offset(0, 4)　'在庫不足数=最少在庫数-在庫数
End With

部品注文数処理

・部品注文数=最大在庫数-在庫数

With Knskcell
　　.Offset(0, 7) = .Offset(0, 4) - .Offset(0, 5)　'過剰在庫数=在庫数-最大在庫数
　　.Offset(0, 8) = .Offset(0, 6) - .Offset(0, 4)　'在庫不足数=最少在庫数-在庫数
　　.Offset(0, 9) = .Offset(0, 5) - .Offset(0, 4)　'部品注文数=最大在庫数-在庫数
End With

部品合計金額処理

・部品合計金額=在庫数×部品単価

With Knskcell
　　.Offset(0, 7) = .Offset(0, 4) - .Offset(0, 5)　'過剰在庫数=在庫数-最大在庫数
　　.Offset(0, 8) = .Offset(0, 6) - .Offset(0, 4)　'在庫不足数=最少在庫数-在庫数
　　.Offset(0, 9) = .Offset(0, 5) - .Offset(0, 4)　'部品注文数=最大在庫数-在庫数
　　.Offset(0, 11) = .Offset(0, 4) * .Offset(0, 10)　'部品合計金額=在庫数*部品単価
End With

動作確認しましょう。

入出庫した際、過剰在庫数・在庫不足数・部品注文数・部品合計金額が
算出されていますか?

まとめ

次回　もうちょい項目追加するよ

セルの値がマイナスの場合0にする。あと項目追加など　【VBA在庫管理#24】

やる気スイッチ入ってますか?　どうもoReです。 今回もデータベース項目の追加などしていきます。 マイナスは0表示させる 前回、項目を追加して動作確認したと思いますが、 なんかわかりにくくないですか? 過剰在庫数が-1だっ...

oregramming.com

2020.01.13

ExcelVBA部品在庫管理【目次】へ戻る